Consulta con el equipo de Windows

'==================================================

'= =

'= Hardcoded Namespace security script generator =

'= =

'==================================================

namespace = InputBox("Create hardcoded Namespace security script for what namespace?" & vbcrlf & vbcrlf & "For example..." & vbcrlf & "root" & vbcrlf & "root\default")

DumpSD(namespace)

Sub DumpSD(strNamespace)

Set objSecurity=GetObject("WinMgmts:{impersonationLevel=impersonate}!" & strNamespace & ":__SystemSecurity=@")

ret = objSecurity.GetSD(strSD)

if ret > 0 then

wscript.echo "Failed to get Namespace Security : Return Code " & ret

wscript.quit

end if

Const ForReading = 1, ForWriting = 2, ForAppending = 8

Dim fso, f

Set fso = CreateObject("Scripting.FileSystemObject")

Set f = fso.OpenTextFile("SetNamespaceSDScript_vbs.txt", ForWriting, True)

f.Writeline ""

f.writeline "Set objSecurity=GetObject(""WinMgmts:{impersonationLevel=impersonate}!" & strNamespace & ":__SystemSecurity=@"")"

f.Writeline ""

init = false

text = "strSD = Array("

start = 1

for each byteval in strSD

if init = true then

text = text & "," & byteval

else

text = text & byteval

init = true

end if

next

text = text & ")" & vbcrlf

f.Writeline text

f.writeline "ret = objSecurity.SetSD(strSD)" & vbcrlf

f.writeline "wscript.Echo ""__SystemSecurity.SetSD() completed : Return Code = "" & ret" & vbcrlf

f.Close

end sub

'Disclaimer

'The sample scripts are not supported under any Microsoft standard support program or service. 'The sample scripts are provided AS IS without warranty of any kind. Microsoft further disclaims 'all implied warranties including, without limitation, any implied warranties of merchantability or 'of fitness for a particular purpose. The entire risk arising out of the use or performance of the 'sample scripts and documentation remains with you. In no event shall Microsoft, its authors, or 'anyone else involved in the creation, production, or delivery of the scripts be liable for any 'damages whatsoever (including, without limitation, damages for loss of business profits, 'business interruption, loss of business information, or other pecuniary loss) arising out of the use 'of or inability to use the sample scripts or documentation, even if Microsoft has been advised of 'the possibility of such damages.